scale caption - dockers reset caption

[gorgo]

This is strange. Would you test this please?
This code will show the worldscale in the caption (Thanks Shelby/John).
When click on docker (eg. contour, scrapbook, fillet/chamfer) the caption is lost. Help please.

Sub ScaleCaption()
    Dim NewCaption As String
    Dim lngVersion As Long
    Dim strVersion As String, strWorldScale As String
    
    If Not ActiveDocument Is Nothing Then
        lngVersion = Application.VersionMajor
        Select Case lngVersion
            Case 13
                strVersion = "X3"
            Case 14
                strVersion = "X4"
            Case 15
                strVersion = "X5"
            Case Else
                strVersion = CStr(lngVersion)
        End Select
        
        Select Case ActiveDocument.WorldScale
            Case 1
                strWorldScale = "1"" = 1"""
            Case 2
                strWorldScale = "Half"
            Case 4
                strWorldScale = "3"" = 1'"
            Case 8
                strWorldScale = "1-1/2"" = 1'"
            Case 12
                strWorldScale = "1"" = 1'"
            Case 16
                strWorldScale = "3/4"" = 1'"
            Case 24
                strWorldScale = "1/2"" = 1'"
            Case 32
                strWorldScale = "3/8"" = 1'"
            Case 48
                strWorldScale = "1/4"" = 1'"
            Case 64
                strWorldScale = "3/16"" = 1'"
            Case 96
                strWorldScale = "1/8"" = 1'"
            Case 128
                strWorldScale = "3/32"" = 1'"
            Case Else
                strWorldScale = ActiveDocument.WorldScale
        End Select
        NewCaption = "CorelDRAW " & strVersion & " ¨'¨l¨'¨ " & strWorldScale
        If AppWindow.Caption <> NewCaption Then AppWindow.Caption = NewCaption
    End If
End Sub

*UPDATE - This happens when you fold-out (expand) a docker.

[runflacruiser]

Hi.
Yes. In order to retain the caption throughout program use you will have to trigger this sub with an event. Most likely SelectionChange.
-John

[gorgo]

Originally Posted by runflacruiser

Hi.
Yes. In order to retain the caption throughout program use you will have to trigger this sub with an event. Most likely SelectionChange.
-John

Interesting...care to show me how please?

[runflacruiser]

Hi.
In the ThisMacroStorage module for the project put

Private Sub GlobalMacroStorage_SelectionChange()
    YourModuleName.ScaleCaption
End Sub

where YourModuleName is the name of the module with the ScaleCaption code.

-John

[gorgo2]

good stuff.
it switches when docker is selected, but restores the scale caption upon selecting the drawing page. weird but that's much better than before.

Thanks much John.

[runflacruiser]

HI.
Yea. Anytime a selection is changed in the document this code is triggered. Don't put much in this event as it runs often.
-John